Cách dùng hàm IF với nhiều điều kiện trong Excel

Bài viết này, do Blog Siêu Marketing soạn thảo, sẽ chỉ dẫn bạn đọc cách áp dụng hàm IF đa điều kiện trong Excel.

Hàm IF, một công cụ điều kiện thường xuyên được sử dụng trong Excel, có thể được thao tác dễ dàng ở mức cơ bản. Tuy nhiên, hàm này sẽ gặp phải những khó khăn khi những điều kiện cần xét tăng lên về số lượng cũng như độ phức tạp, đặc biệt là đối với người mới làm quen với việc viết hàm IF lồng nhiều điều kiện.

Microsoft Excel đặt ra một giới hạn về số lượng hàm IF có thể lồng chồng lên nhau. Với phiên bản Excel từ năm 2003 trở lại trước, chỉ có thể lồng được tối đa 7 hàm IF. Còn đối với các phiên bản mới hơn như Excel 2021, Excel 2019, Excel 365, Excel 2016, Excel 2013, Excel 2010, Excel 2007, con số này tăng lên tới 64 hàm IF có thể lồng vào nhau.

Áp dụng hàm IF với nhiều điều kiện chồng chéo

Dưới đây là một ví dụ đơn giản về hàm IF lồng với nhiều điều kiện: Phân loại điểm số sinh viên. Các điều kiện phân loại như sau:

  • Loại A: điểm số cao hơn 249
  • Loại B: điểm số từ 200 tới 249, kể cả 200
  • Loại C: điểm số từ 150 tới 199, kể cả 150
  • Loại D: điểm số thấp hơn 150

Dựa theo các điều kiện trên, ta sẽ xây dựng hàm IF đa điều kiện như sau:

=IF(
    B2 > 249,
    "A",
    IF(
        B2 >= 200,
        "B",
        IF(
            B2 >= 150,
            "C",
            "D"
        )
    )
)

Sau đây là kết quả khi áp dụng công thức IF được viết ở trên:

ham-if-nhieu-dieu-kien-01

Chú ý Khi bạn viết công thức trong Excel và thực hiện xuống dòng hay lùi một đoạn nhất định sẽ giúp công thức trở nên rõ ràng và dễ nhìn hơn. Để xuống dòng, bạn có thể sử dụng tổ hợp phím ALT + Enter hoặc dùng công cụ soạn thảo công thức, công cụ này được Thanh chuẩn bị để tạo độ thẩm mỹ cho công thức.

Cách tiếp cận hàm IF lồng ghép

Đối với nhiều người, hiểu cặn kẽ cấu trúc hàm IF có nhiều điều kiện lần lượt hỗ tương đôi khi gây khó khăn. Điều này là điều dễ hiểu khi đối mặt với một hàm IF lồng nhau phức tạp. Nhưng, nếu phân biệt được rõ ràng các thành phần của hàm IF, việc nắm bắt được bản chất của hàm IF đa điều kiện này trở nên thuận lợi hơn. Hãy xem xét biểu đồ dưới đây để làm sáng tỏ điều này.

ham-if-nhieu-dieu-kien

Biểu đồ trình bày về hàm IF lồng ghép có thể được hiểu như sau:

Chúng ta sẽ bắt đầu:

Kiểm tra giá trị của biến B2 có lớn hơn 249 hay không

Nếu kết quả là đúng, sẽ trả về “A” làm kết quả của hàm IF

Nếu sai, ta sẽ tiếp tục kiểm tra biến B2 với giá trị lớn hơn hoặc bằng 200

Và nếu điều này đúng, sẽ trả về “B”

Nếu không, tiếp tục kiểm tra với ngưỡng 150

Nếu biến B2 lớn hơn hoặc bằng 150, trả về “C”

Còn không, ta sẽ kết thúc với “D”

Phối hợp hàm IF với các công thức khác trong việc tính toán

Bây giờ, chúng ta sẽ xem xét một ví dụ khác khi thực hiện tích hợp điều kiện IF với việc tính toán doanh thu. Giả sử bạn đang kinh doanh với cơ chế giảm giá theo số lượng mua hàng – mua càng nhiều, giá càng hợp lý. Dưới đây là bảng tính giảm giá:

Số lượng Giá mỗi đơn vị
1 – 10 $20
11 – 19 $18
20 – 49 $16
50

1 – 10 $20
11 – 19 $18
20 – 49 $16
50 – 100 $13
Trên 101 $12

Chúng ta cần tính tổng số tiền dựa trên số lượng sản phẩm được chỉ định trong ô B8 và đưa công thức thích hợp vào ô B9.

ham-if-nhieu-dieu-kien-03

Công thức này ở ô B9 có thể được viết như sau:

=B8 *
IF(B8 >= 101,B6,
    IF(B8 >= 50,B5,
        IF(B8 >= 20,B4,
            IF(B8 >= 11,B3,
                IF(B8 >= 1,B2,"")
            )
        )
    )
)

Nếu số lượng sản phẩm không nằm trong phạm vi chúng ta xác định, ta có thể dùng hàm IF kết hợp với điều kiện khác như dưới đây:

ham-if-nhieu-dieu-kien-04

Áp dụng công thức dưới đây:

=IF(
    OR(B8 > 200,B8 < 1),"Qty. out of range", B8 * IF(B8 >= 101,12,
        IF(B8 >= 50,13,
            IF(B8 >= 20,16,
                IF(B8 >= 11,18,
                    IF(B8 >= 1,20,"")
                )
            )
        )
    )
)

Khi kết hợp hàm IF và hàm CONCATENATE

Bạn cũng có thể sử dụng cả hàm IF và hàm Concatenate cho mục đích ánh xạ nhiều giá trị hoặc thay đổi giá trị theo một “bảng tra cứu” do bạn định sẵn.

ham-if-nhieu-dieu-kien-05

Để kết hợp hai hàm này, bạn có thể sử dụng công thức sau tại ô C2:

=CONCATENATE(
    IF(B2 = "a","Excellent",""),
    IF(B2 = "b","Good",""),
    IF(B2 = "c","Satisfactory",""),
    IF(B2 = "d","Poor","")
)

Lưu ý: Bởi vì sự so sánh với dấu “=” không quan tâm đến chữ hoa hay chữ thường, việc viết B2 = "a" hoặc B2 = "A" đều được chấp nhận trong công thức giống như trên.

Vài lưu ý khi dùng hàm IF với nhiều điều kiện và hàm lồng nhau

Sắp xếp thứ tự điều kiện

Trình tự điều kiện trong hàm IF lồng nhau rất quan trọng vì Excel đánh giá các biểu thức theo thứ tự chúng được liệt kê trong công thức. Ví dụ:

Nếu B2 = 283 và bạn so sánh hai cách sử dụng hàm IF:

Cách thứ nhất:

=IF(B2 > 249,"A",
    IF(B2 >= 200,"B",
        IF(B2 > 150,"C","D")
    )
)

Cách thứ hai:

=IF(B2 > 150,"C",
    IF(B2 > 200,"B",
        IF(B2 > 249,"A","D")
    )
)

Trong trường hợp này, nếu dùng cách thứ hai và điểm của sinh viên là 283, sinh viên đó sẽ được xếp hạng “C” vì Excel sẽ không xét đến các biểu thức còn lại sau khi tìm được biểu thức đúng đầu tiên. Do đó, việc sắp xếp các điều kiện theo đúng trật tự là cần thiết khi viết hàm IF.

Công cụ viết công thức để làm cho hàm IF dễ nhìn

Viết công thức mặc dù để dễ đọc sẽ giúp ích trong việc phát triển công thức và rất hữu ích trong việc hiểu công thức nếu bạn cần xem lại sau này. Viết công thức dễ hiểu sẽ giúp giảm thiểu lỗi và tiết kiệm thời gian đáng kể khi bạn cần phải giải thích hoặc hiểu công thức của mình.

Bộ công cụ đã được chuẩn bị sẵn sàng để hỗ trợ các bạn:

Điều chỉnh định dạng của công thức Excel giúp dễ theo dõi hơn

Phương tiện khác có thể thay thế hàm IF trong Excel

Có một nguyên tắc chung, việc sở hữu nhiều lựa chọn để thực hiện nhiệm vụ bao giờ cũng là điều cần thiết, và như hàm IF, không phải lúc nào nó cũng là cần thiết trong mọi tình huống, bởi lẽ chúng ta có các phương án thay thế sau đây:

  1. Trong trường hợp cần kiểm tra đa điều kiện và muốn nhận nhiều đáp án khác biệt, hàm choose có thể được sử dụng thay thế cho việc lồng ghép nhiều hàm IF.
  2. Khi cần tham chiếu đến một khoảng cụ thể, việc áp dụng hàm VLOOKUP cùng với bảng tham khảo sẽ giúp đơn giản hóa công thức một cách đáng kể.
  3. Trong một số tình huống cụ thể, lựa chọn tối ưu là áp dụng VBA trong Excel để rõ ràng hóa điều kiện và tránh làm cho các công thức phức tạp và khó quản lý sau này.

Đó là những giải đáp xoay quanh chủ đề hàm IF lồng nhau có nhiều điều kiện mà tôi muốn truyền đạt đến các bạn thông qua bài viết này, hy vọng rằng những kiến thức này sẽ hữu ích để bạn áp dụng một cách hiệu quả trong công việc. Đừng quên thử những khóa học khác mà tôi đã giới thiệu.

Trương Thành Tài
0
    0
    Đơn hàng
    Đơn hàng trốngQuay lại Shop